Introducción al Cálculo en Mathematica

cálculo simbólico matemáticas introducción

Este es un breve tutorial introductorio a las herramientas relativas al Cálculo que ofrece Wolfram Mathematica. Sus objetivos son presentar cómo se escriben y manejan funciones de una variable real y cómo pueden representarse. Además de una guía de referencia, Wolfram pone a disposición una Introducción «rápida» a Mathematica y su lenguaje que se extiende mucho más allá de lo que pretende el presente tutorial.

Aritmética básica

  • Operadores aritméticos: +, -, *, /, ^
  • Delimitadores: (, ), .

Los corchetes [] y las llaves {} están reservados para otras construcciones.

Ejemplo.

Los ejemplos pueden copiarse y ejecutarse directamente en Mathematica.

2 + 3
7 - 4
5 * 6
8 / 2
2^3
(3 - (7/5))^2
3 - 7/5^2

Ejercicio. Calcula las siguientes expresiones:

  1. \(\frac{12}{3} + 5 \cdot 2\)
  2. \(2^5 - (3+1)^2\)
  3. \(\sqrt{1 + \frac79}\)

Ejercicio. Calcula las siguientes expresiones: \(1+\frac1{10}\), \(1+0.1\) y \(1.0+\frac1{10}\); y observa las diferencias entre ellas. ¿Qué conclusión sacas?

Teclas (en GUI)

  • ↵ Return: nueva línea
  • ⌅ Enter: ejecuta celda + nueva celda
  • ⇧ Shift + ↵ Return: igual que ⌅ Enter
  • ⌥ Alt (Opt) + Enter: nueva celda
  • Fl. ↑ arriba/↓ abajo: cambia de celda

En muchos teclados existen dos teclas etiquetadas como «Enter», lo que ha llevado a diferenciarlas como «Enter alfabético» (↵ Return) y «Enter numérico» (⌅ Enter). La confusión aumenta en los teclados sin bloque numérico, ya que sólo cuentan con una tecla rotulada como «Enter», aunque técnicamente corresponde a ↵ Return. En los teclados con rotulación en español, la ambigüedad es aún mayor, pues las teclas pueden aparecer indistintamente como «Intro» o «Entrar».

Variables

Asignación

  • =: asignación inmediata (evaluación en el momento)
  • :=: asignación diferida (evaluación al usar)
  • =.: limpieza de definiciones (unassign, desasignación)

Ejemplo.

x = 5
y = x^2
x = 3
y
x =.
y =.

Ejercicio. Calcula \(12345^4 - 2\cdot12345^3 - 3\cdot12345^2 - 4\cdot12345\).

  1. Define una variable a con valor 12345.
  2. Define b como a^4-2*a^3-3*a^2-4*a usando asignación inmediata.
  3. Cambia el valor de a a 1 y comprueba el valor de b.

Constantes

  • Pi: el número \(\pi\)
  • E: el número de Euler
  • I: el número imaginario \(i\)
  • Infinity: infinito \(\infty\)
  • GoldenRatio: número áureo \(\phi\)

Ejercicio. Comprueba la famosa fórmula de Euler: \(e^{i\pi}+1=0\).

Expresiones

En Mathematica, todo se representa como una expresión, desde operaciones aritméticas hasta funciones, operadores y estructuras de control. Internamente, estas expresiones se organizan como árboles, ramificándose según los argumentos de cada función, lo que permite analizarlas y transformarlas simbólicamente.

Ejemplo.

y = x^2
x = 5; y
x = 3; y
x =. ; y
y =.
x

Ejercicio. Calcula \(r = \sqrt{a^2 + b^2}\) para distintos valores de \(a\) y \(b\).

  1. Define r usando asignación diferida.
  2. Define a = 1 con asignación inmediata y evalúa r.
  3. Define b = -Sqrt[3] y evalúa r.
  4. Limpia a y evalúa r.

Condiciones y operadores lógicos

Los operadores lógicos devuelven True o False. Todos son binarios, excepto la negación (!), que es unaria.

  • ==, !=, >, <, >=, <=
  • && (y), || (o), ! (no)

Ejemplo.

x = 2
x^2 > 5 || x != 3
x = 3
cond := x^2 > 5 || x != 3
x = 2.5
!cond

Funciones

Además de las variables, otro elemento fundamental en Mathematica son las funciones. El sistema incluye muchas funciones predefinidas, y permite al usuario definir las suyas propias.

Funciones internas

  • Sqrt[x], Exp[x], Log[x], Sin[x], Cos[x]
  • Factorial[n], Binomial[n, k], Floor[x], Ceiling[x]

Ejemplo.

Sqrt[4]
Log[E^2]
Sin[Pi/3]
Floor[1.5]

FF. definidas por el usuario

Se definen con asignación diferida: NombreFuncion[var1_, …, varN_] := expr donde expr es una expresión que depende de var1,...,varN. El guion bajo _ es obligatorio y representa un argumento.

Ejemplo.

f[x_] := 1 + x^2
f[2]

Ejercicio.

  1. Define una función \(g(x) = x^3 - 2x + 1\).
  2. Evalúa \(g(0)\), \(g(2)\), y \(g(-1)\).

Ejercicio. Define una función Dist que calcule la distancia al origen de un punto de coordenadas \((a, b)\) y comprueba su funcionamiento.

FF. definidas a trozos

Se definen con Piecewise[{{val1, cond1}, {val2, cond2}, …}, val], donde val es el valor por defecto si no se cumple ninguna condición.

Ejemplo.

f[x_] := Piecewise[{{x^2, x < 0}, {x, x >= 0}}]
f[3]
f[-2]

Ejercicio. Usa Piecewise para definir una función que sea:

  • \(\log(1+x)\) si \(x < 0\)
  • \(x/2-1\) si \(0\leq x \leq 3\)
  • \(1-(x-4)^2\) si \(x > 3\)

Procedimientos

Mathematica incluye funciones avanzadas para resolver ecuaciones, derivar, integrar, etc.

  • Solve[eq, x]: resuelve ecuaciones simbólicas
  • Limit[f[x], x -> a]: cálculo de límites
  • D[f[x], x]: derivadas
  • Integrate[f[x], x]: integrales

Ejemplo.

Solve[x^2 - 4 == 0, x]
Limit[Sin[x]/x, x -> 0]
D[x^3 + 2*x, x]
Integrate[x^2, x]

Ejercicio.

  1. Resuelve \(x^2 + 5x + 6 = 0\).
  2. Calcula \(\lim_{x \to \infty} \frac{1}{x}\).
  3. Deriva \(\sin(x^2)\).
  4. Ejecuta D[x^3 + 2*x, {x, 2}] e interpreta el resultado.
  5. Ejecuta Integrate[x^2, {x, 1, 2}] e interpreta el resultado.

Cálculo simbólico vs. numérico

Mathematica permite trabajar tanto con expresiones simbólicas como con cálculos numéricos.

Funciones de cálculo simbólico

  • Expand: desarrolla expresiones
  • Simplify: simplifica expresiones

Ejemplo.

Expand[(1 + x)^5]
Simplify[(1 - 2*x + x^2)/(x - 1)]
Simplify[Sqrt[x^2]]
Simplify[Sqrt[x^2], Element[x, Reals]]

Ejercicio.

  1. Expande \((x-2)^4\).
  2. Simplifica \(\frac{x^2-1}{x-1}\).
  3. Simplifica \(\sqrt{x^2}\) asumiendo que \(x<0\).
  4. Calcula las raíces de \(x^2-4\).

Funciones de cálculo numérico

  • N[expr]: evalúa numéricamente
  • NSolve[eq, x]: resuelve numéricamente
  • NIntegrate[f[x], {x, a, b}]: integra numéricamente

Ejemplo.

N[Pi]
NSolve[Exp[-x] == x, Reals]
NIntegrate[Exp[-x^2], {x, 0, 1}]

Ejercicio.

  1. Calcula numéricamente \(g(\frac12)\) de dos formas, donde \(g(x)=x^2-1\).
  2. Calcula \(\int_0^1 \frac1{1+x^2} \text{d}x\) numéricamente.
  3. Resuelve numéricamente \(\cos(x) = x\).

Representación gráfica

Mathematica ofrece potentes herramientas gráficas. La más básica es Plot, que puede combinarse con Show.

  • Plot[f[x], {x, a, b}]: gráfica en 2D
  • Show: combina gráficas
  • Plot3D[f[x, y], {x, a, b}, {y, c, d}]: gráfica en 3D
  • ContourPlot, ParametricPlot, ListPlot, BarChart, Histogram

Ejemplo.

Plot[Sin[x], {x, 0, 2*Pi}]
Plot[{Sin[x], Cos[x]}, {x, 0, 2*Pi}]
Show[
  Plot[Sin[x], {x, 0, 2*Pi}],
  Plot[Cos[x], {x, -Pi, Pi}],
  PlotRange -> All
]
Plot3D[x^2 + y^2, {x, -2, 2}, {y, -2, 2}]

Ejercicio.

  1. Grafica \(x^2-4x+3\) en el intervalo [0, 5].
  2. Representa alguna de las funciones definidas a trozos anteriores en el mismo intervalo.
  3. Combina las gráficas de dos formas diferentes.

Ejercicio. Dibuja en 3D la función \(f(x,y)=\sin(xy)\).

Previous Post